3Dイベント

3Dイベント

  1. 球体モデルをクリックしたらイベントへ飛ぶ
  2. 箱または球体モデルをクリックしたらイベントへ飛ぶ
  3. 3Dイベントの停止
  4. 3Dイベントの削除

球体モデルをクリックしたらイベントへ飛ぶ

こちらは球体モデルをクリックしたらイベント(指定のラベル)に飛ぶスクリプトです。
3dev.JPG

* scene1
; 3D機能を利用できるようにする
[3d_init ]


;3Dの球体を定義する
[3d_sphere_new name="sphere" ]
[3d_show name="sphere" pos="0,0,0" rot="0,0.0,0" scale="1,1,1" time=2000 ]


;イベントの定義 ボタン同様に[s]が必要
[3d_event name="sphere" target="sphere_click"]
[s]

* sphere_click
;メッセージボックスを表示
@layopt layer="message" visible=true
sphere3Dモデルがクリックされました[p]
@jump target="common"

* common
イベントを再開します[p]
; 再度イベントを発生させたい場合は[3d_event_start]を通過する必要があります。
[3d_event_start]
元の位置に戻ります。[p]
;メッセージボックスを非表示
@layopt layer="message" visible=false
@jump target="scene1"
[s]

箱または球体モデルをクリックしたらイベントへ飛ぶ

1box_ev.JPG spha_ev1.JPG
球体の色を指定してますが、この画像です。気にしないでください。
* scene1
; 3D機能を利用できるようにする
[3d_init ]


;3Dの箱を定義する
[3d_box_new name="mybox" width=100 height=100 depth=100 color="0x00d9ff" pos="-500,30,0" rot="0,0,0" scale="1,1,1" ]
;定義した箱を実際に画面に表示する
[3d_show name="mybox"]
;3Dの球体を定義する
[3d_sphere_new name="sphere1" color="0x00d9ff"]
;定義した球体を実際に画面に表示する
[3d_show name="sphere1" pos="5,0,0" rot="0,0.0,0" width=30 height=30 scale="1,1,1"]
;~~~~位置調整デバッグ↓コメントを外して利用~~~~
;[3d_debug name="mybox"]
;[3d_debug name="sphere1"]
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;イベントの定義
[3d_event name="mybox" target="box_click"]
[3d_event name="sphere1" target="sphere_click"]
[s]



* sphere_click
;メッセージボックスを表示
@layopt layer="message" visible=true
sphere3Dモデルがクリックされました[p]
@jump target="common"

* box_click
;メッセージボックスを表示
@layopt layer="message" visible=true
box3Dモデルがクリックされました[p]
@jump target="common"


* common
イベントを再開します[p]
;メッセージボックスは非表示
@layopt layer="message" visible=false
@3d_event_start
@jump target="scene1"
[s]




3Dイベントの停止

登録した3Dイベントを停止させます。 削除せずに存在はしている状態です。
[3d_event_stop name=object_name]
[3d_event_start]で再開できます。
再度イベントを開始したい時などに。

3Dイベントの削除

イベントの定義を削除します。 削除後はクリックしても反応しません。
[3d_event_delete name="object_name"]
全て[3d_delete_all] 

[3d_event]再定義しない限りは反応しません。
モデルは表示しておきたいけれどイベントは表示しておきたくないなどに。

  • 最終更新:2021-03-15 13:21:52

このWIKIを編集するにはパスワード入力が必要です

認証パスワード