config.ksシナリオについての追記

デフォルトのconfig.ksについての追記です。config.tjsではありません。※何かあれば追記修正して下さい。

config.ksについての追記 項目

多量のスクリプトを目にしてカスタムできない!という思い込みを防止するページです。※但しタグリファレンスの参照は必須。

  1. config.ksとは
  2. 注釈1 config.tjsの内容を利用する
  3. 注釈2 背景表示、タイトル画面に戻るボタン表示
  4. 注釈3 BGM音量ボタンup・down
  5. 注釈4 SE音量ボタンup・down
  6. 注釈5 メッセージスピードボタン
  7. 注釈6 オートスピード
  8. 注釈7 メッセージ、オートのスピードの表示変更
  9. 注釈8 未読スキップon・offボタン
  10. 注釈9 common [s]
  11. 注釈10(未)
  12. 注釈11 BGM音量を下げる処理
  13. 注釈12 BGM音量を上げる処理
  14. 注釈13 SE音量を下げる処理
  15. 注釈14 SE音量を上げる処理
  16. 注釈15 テキストスピード、ボタンの位置変更
  17. 注釈16 テキストスピード表示
  18. 注釈17 オートスピード変更
  19. 注釈18 未読スキップoff表示変更
  20. 注釈19 未読スキップon表示変更
エンティティとは?→変数関係を参照。タグの数値に変数を代入できること。&f.hensu で出来る。変数関係を参照。
メニューにもどる。

その他のこと

別途、コンフィグの状態を引き継ぎしたい場合は、システム変数で分岐処理【if】を使用等してください。 first.ksやmake.ksに書き込む。またはサブルーチン(マクロ)で分岐処理をして下さい。
一時変数をシステム変数に変えるなど
◆ここを見る前に
変数と分岐がわからない場合、変数については変数関係
【if】については基礎制御構文関係を参照して下さい。

config.ks

viewCode→data/sinario/config.ks を参照
制作者さまのご好意によって付属されたコンフィグ画面用のシナリオ。過去より大幅にタグで作れるようになりました。 デフォルトのシナリオ名はconfig.ksです。
ゲーム内で呼び出す時はボタンroleのsleepgameを使用しましょう。ボタン表示roleにて参照。

詳細をみる

config.ks 注釈1

[iscript]
    tf.current_bgm_vol = parseInt(TG.config.defaultBgmVolume);
    tf.current_se_vol = parseInt(TG.config.defaultSeVolume);

    tf.current_ch_speed = parseInt(TG.config.chSpeed);
    tf.current_auto_speed = parseInt(TG.config.autoSpeed);

    tf.text_skip ="ON";

    if(TG.config.unReadTextSkip != true){
        tf.text_skip ="OFF";
    } 

[endscript]

◼︎注釈1

詳細をみる

ページ最上部へ

config.ks 注釈2

[layopt layer=1 visible=true]

[cm]
[bg time=300 storage="cgbg.png"]
[ptext layer=1 page=fore text="Game Config" x=20 y=20 size=32 color=0xA8401C visible=true]
[button graphic="back_title.gif" target="*backtitle" x=730 y=20 ]
@jump target="*config_page"

◼︎注釈2

この辺りからはタグリファレンスを参照

詳細をみる

ページ最上部へ

config.ks 注釈3

*config_page

;BGM音量
[ptext layer=1 page=fore text="BGM 音量:" x=40 y=145 size=26 color=black visible=true]
[ptext name="text_bgm_vol" layer=1 page=fore text="&tf.current_bgm_vol" x=190 y=150 size=26 color=black visible=true]
[button fix="true" target="*vol_bgm_up" graphic=config/arrow_up.gif width=35 height=35 x=300 y=150  ]
[button fix="true" target="*vol_bgm_down" graphic=config/arrow_down.gif width=35 height=35 x=340 y=150  ]

◼︎注釈3

詳細をみる

ページ最上部へ

config.ks 注釈4

;SE音量
[ptext layer=1 page=fore text="SE 音量:" x=40 y=195 size=26 color=black visible=true]
[ptext name="text_se_vol" layer=1 page=fore text="&tf.current_se_vol" x=190 y=200 size=26 color=black visible=true]
[button fix="true" target="*vol_se_up" graphic=config/arrow_up.gif width=35 height=35 x=300 y=200  ]
[button fix="true" target="*vol_se_down" graphic=config/arrow_down.gif width=35 height=35 x=340 y=200  ]

◼︎注釈4

詳細をみる

ページ最上部へ

config.ks 注釈5

◼︎5-1詳細をみる

◼︎5-2 メッセージスピードのボタン
[button name="ch,ch_100" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=100" graphic=config/01.gif width=35 height=35 x=360 y=270 ]
[button name="ch,ch_80" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=80" graphic=config/02.gif width=35 height=35 x=390 y=270 ]
[button name="ch,ch_50" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=50" graphic=config/03.gif width=35 height=35 x=420 y=270 ]
[button name="ch,ch_40" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=40" graphic=config/04.gif width=35 height=35 x=450 y=270 ]
[button name="ch,ch_30" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=30" graphic=config/05.gif width=35 height=35 x=480 y=270 ]
[button name="ch,ch_25" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=25" graphic=config/06.gif width=35 height=35 x=510 y=270 ]
[button name="ch,ch_20" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=20" graphic=config/07.gif width=35 height=35 x=540 y=270 ]
[button name="ch,ch_11" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=11" graphic=config/08.gif width=35 height=35 x=570 y=270 ]
[button name="ch,ch_8" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=8" graphic=config/09.gif width=35 height=35 x=600 y=270 ]
[button name="ch,ch_5" fix="true" target="*ch_speed_change" exp="tf.set_ch_speed=5" graphic=config/10.gif width=35 height=35 x=630 y=270 ]

◼︎注釈5

5-1は、テキスト表示のみなので割愛
5-2…ボタン表示

詳細をみる

ページ最上部へ

config.ks 注釈6

◼︎6-1詳細をみる

◼︎6-2 オートモードにおけるメッセージスピードのボタン
[button fix="true" name="auto,auto_5000" target="*auto_speed_change" exp="tf.set_auto_speed=5000;tf.text_auto=0" graphic=config/01.gif width=35 height=35 x=360 y=330 ]
[button fix="true" name="auto,auto_4500" target="*auto_speed_change" exp="tf.set_auto_speed=4500;tf.text_auto=1" graphic=config/02.gif width=35 height=35 x=390 y=330 ]
[button fix="true" name="auto,auto_4000" target="*auto_speed_change" exp="tf.set_auto_speed=4000;tf.text_auto=2" graphic=config/03.gif width=35 height=35 x=420 y=330 ]
[button fix="true" name="auto,auto_3500" target="*auto_speed_change" exp="tf.set_auto_speed=3500;tf.text_auto=3" graphic=config/04.gif width=35 height=35 x=450 y=330 ]
[button fix="true" name="auto,auto_3000" target="*auto_speed_change" exp="tf.set_auto_speed=3000;tf.text_auto=4" graphic=config/05.gif width=35 height=35 x=480 y=330 ]
[button fix="true" name="auto,auto_2500" target="*auto_speed_change" exp="tf.set_auto_speed=2500;tf.text_auto=5" graphic=config/06.gif width=35 height=35 x=510 y=330 ]
[button fix="true" name="auto,auto_2000" target="*auto_speed_change" exp="tf.set_auto_speed=2000;tf.text_auto=6" graphic=config/07.gif width=35 height=35 x=540 y=330 ]
[button fix="true" name="auto,auto_1000" target="*auto_speed_change" exp="tf.set_auto_speed=1000;tf.text_auto=7" graphic=config/08.gif width=35 height=35 x=570 y=330 ]
[button fix="true" name="auto,auto_800" target="*auto_speed_change" exp="tf.set_auto_speed=800;tf.text_auto=8" graphic=config/09.gif width=35 height=35 x=600 y=330 ]
[button fix="true" name="auto,auto_500" target="*auto_speed_change" exp="tf.set_auto_speed=500;tf.text_auto=9" graphic=config/10.gif width=35 height=35 x=630 y=330 ]

◼︎注釈6

6-1は、テキスト表示のみなので割愛
6-2…ボタン表示

詳細をみる

ページ最上部へ

config.ks 注釈7

[iscript]
$(".ch_"+tf.current_ch_speed).css("top",260);
$(".auto_"+tf.current_auto_speed).css("top",320);
[endscript]

◼︎注釈7

詳細をみる

ページ最上部へ

config.ks 注釈8

;未読スキップ
[ptext layer=1 page=fore text="未読スキップ:" x=40 y=400 size=26 color=black visible=true]
[ptext name="text_skip" layer=1 page=fore text="&tf.text_skip" x=230 y=405 size=26 color=black visible=true]

[button fix="true" target="*skip_off" graphic=config/off.gif width=85 x=340 y=405 ]
[button fix="true" target="*skip_on" graphic=config/on.gif width=85 x=440 y=405 ]

◼︎注釈8

詳細をみる

ページ最上部へ

config.ks 注釈9

@jump target="*common"
*page_2
@jump target="*common"

*common

*endpage
[s]

◼︎注釈9

@jump target="*common"で*endpageに飛ばして[s]で止めている。

詳細をみる

[s]があることによって画像ボタンが作動するようになる。
ページ最上部へ

config.ks 注釈10

*backtitle
[cm]
[freeimage layer=1]
@clearfix

@jump storage=title.ks

*nextpage
[freeimage layer=1]
[cm]
@jump storage="first.ks" target="*start"


*backpage
[emb exp="tf.page--;"]
@jump target="*cgpage"

*clickcg

[return]

*no_image

;@jump  target=*cgpage


◼︎注釈10

◼︎backtitle 【注釈1】のボタンのジャンプ先
fixボタンやテキストをクリアしてタイトル画面title.ksにジャンプ@jump storage=title.ks
◼︎nextpage…以下まだありません
◼︎backpage…
◼︎clickcg…
◼︎return…
◼︎noimage…
ページ最上部へ

config.ks 注釈11

*vol_bgm_down

[iscript]
if(tf.current_bgm_vol != 0){
    tf.current_bgm_vol -= 10;    
    $(".text_bgm_vol").html(tf.current_bgm_vol);
}
[endscript]

[bgmopt volume="&tf.current_bgm_vol"]

[return]

◼︎注釈11

詳細をみる

ページ最上部へ

config.ks 注釈12

*vol_bgm_up
[iscript]
if(tf.current_bgm_vol != 100){
    tf.current_bgm_vol += 10;    
    $(".text_bgm_vol").html(tf.current_bgm_vol);
}
[endscript]
[bgmopt volume="&tf.current_bgm_vol"]

[return]

◼︎注釈12

詳細をみる

ページ最上部へ

config.ks 注釈13

*vol_se_down
[iscript]
if(tf.current_se_vol != 0){
    tf.current_se_vol -= 10;    
    $(".text_se_vol").html(tf.current_se_vol);
}
[endscript]

[seopt volume="&tf.current_se_vol"]

[return]

注釈13

詳細をみる

ページ最上部へ

config.ks 注釈14

*vol_se_up
[iscript]
if(tf.current_se_vol != 100){
    tf.current_se_vol += 10;    
    $(".text_se_vol").html(tf.current_se_vol);
}
[endscript]
[seopt volume="&tf.current_se_vol"]

[return]

◼︎注釈14

詳細をみる

ページ最上部へ

config.ks 注釈15

*ch_speed_change
[iscript]
$(".ch").css("top",270);
$(".ch_"+tf.set_ch_speed).css("top",260);
[endscript]
[configdelay speed="&tf.set_ch_speed"]

注釈15

詳細をみる

ページ最上部へ

config.ks 注釈16

;テキストスピード表示
[position layer="message0" left=10 top=520 width=940 height=220 page=fore visible=true]
@layopt layer=message0 visible=true
テキスト速度テスト
[wait time=2000]
[er]
@layopt layer=message0 visible=false

[return]

注釈16

メッセージスピードをプレビューしてくれる処理
positionでメッセージレイヤーを作成
@layopt layer=message0 でメッセージを可視。
テキスト速度テスト というメッセージを表示。ウェイトしないと表示したかわからないので2秒ウェイト。
[er]でmessage0でメッセージの中をクリアしている
ページ最上部へ

config.ks 注釈17

*auto_speed_change

[iscript]

$(".auto").css("top",330);
$(".auto_"+tf.set_auto_speed).css("top",320);

[endscript]
[autoconfig speed="&tf.set_auto_speed"]

[return]

◼︎注釈17

詳細をみる

ページ最上部へ

config.ks 注釈18

*skip_off
[iscript]
    tf.text_skip = "OFF";
    $(".text_skip").html("OFF");
[endscript]
[config_record_label skip=false]
[return]

◼︎注釈18

◼︎skip_off…ラベル。このラベルからreturnまでが未読スキップをOFF等にする処理
◼︎ tf.text_skip = "OFF"; …一時変数にOFFの文字列を代入
◼︎$(".text_skip").html("OFF"); …ptext name=text_skip のテキストをOFFに変更します。注釈8
◼︎[config_record_label skip=false]…未読スキップをOFFするタグ
◼︎[return]…もどります
ページ最上部へ

config.ks 注釈19

*skip_on
[iscript]
    tf.text_skip = "ON";
    $(".text_skip").html("ON");
[endscript]
[config_record_label skip=true]
[return]

◼︎注釈19

◼︎skip_on…ラベル。このラベルからreturnまでが未読スキップをON等にする処理
◼︎ tf.text_skip = "ON"; …一時変数にONの文字列を代入
◼︎$(".text_skip").html("ON"); …ptext name=text_skip のテキストをONに変更します。注釈8
◼︎[config_record_label skip=true]…未読スキップをONするタグ
◼︎[return]…もどります
ページ最上部へ

  • 最終更新:2016-10-08 20:42:07

このWIKIを編集するにはパスワード入力が必要です

認証パスワード